Back to the Main Page.

ac_define_dir

Download the M4 Source.

Synopsis

AC_DEFINE_DIR(VARNAME, DIR [, DESCRIPTION])

Version

1.4 (2005/01/20)     0.5.63   :   Miscellaneous

Author

Stepan Kasal <kasal@ucw.cz>, Andreas Schwab <schwab@suse.de>, Guido Draheim <guidod@gmx.de>, Alexandre Oliva

Description

This macro _AC_DEFINEs VARNAME to the expansion of the DIR variable, taking care of fixing up ${prefix} and such.

VARNAME is offered as both a C preprocessor symbol, and an output variable.

Note that the 3 argument form is only supported with autoconf 2.13 and later (i.e. only where _AC_DEFINE supports 3 arguments).

Examples:

    AC_DEFINE_DIR(DATADIR, datadir)
    AC_DEFINE_DIR(PROG_PATH, bindir, [Location of installed binaries])

M4 Source Code

AC_DEFUN([AC_DEFINE_DIR], [
  prefix_NONE=
  exec_prefix_NONE=
  test "x$prefix" = xNONE && prefix_NONE=yes && prefix=$ac_default_prefix
  test "x$exec_prefix" = xNONE && exec_prefix_NONE=yes && exec_prefix=$prefix
  eval ac_define_dir="\"[$]$2\""
  AC_SUBST($1, "$ac_define_dir")
  AC_DEFINE_UNQUOTED($1, "$ac_define_dir", [$3])
  test "$prefix_NONE" && prefix=NONE
  test "$exec_prefix_NONE" && exec_prefix=NONE
])